***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan. 8, 2025                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJT138K     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs      s1    s2   205u TC=3m
Rg     g1    g2     162.2
M1      d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=1.42  VTO=1.33  LEVEL=3  VMAX=5e4  ETA=0.006  nfs=1.000e10  gamma=0.45)
Rd     d1    d2    1.050   TC=6m,10u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=55  TBV1=7.455e-4 TBV2=5.055e-10  CJO=4.504e-12  M=2.822e-1  VJ=3.905e-1)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=3.147e-11  N=1.010  RS=4e-8  EG=1.08  TT=20n IKF=6.025e-5 ;tikf=7.5e-4)
Rdiode  d1  21    8.962e-2 TC=1.2m
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   1.188e-11
.MODEL     DGD    D(cjo=1.188e-11   M=4.262e-1   VJ=3.905e-1)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    2.8576e-13
.ENDS PJT138K
*$
